extends Node

# ユニットが選択されたときに発信されるシグナル
signal unit_selected(unit)

# ユニットが移動したときに発信されるシグナル
signal unit_moved(is_move)

extends Resource
class_name UnitDetail

# ユニットの種類を定義（プレイヤー or エネミー）
enum UnitType {
    PLAYER,
    ENEMY,
}

# ユニット名
@export var unit_name: String
# ユニットのタイプ（プレイヤー or エネミー）
@export var unit_type: UnitType
# 攻撃力
@export var unit_attack: int
# 防御力
@export var unit_defense: int
# 最大HP
@export var unit_max_health: int
# 現在のHP
@export var unit_health: int
# 移動範囲
@export var unit_move_range: int
# 攻撃範囲
@export var unit_attack_range: int
# クリティカル発生率
@export var unit_critical_rate: int
# クリティカル時のダメージ倍率
@export var unit_critical_damage: int
# スプライトアニメーション
@export var unit_sprite: SpriteFrames

CharacterUnit (Node2D)
├─ AnimatedSprite2D
├─ Area2D
    └─ CollisionShape2D


@tool
extends Node2D
class_name CharacterUnit

# ユニットの詳細情報（名前・ステータス・スプライト等）
@export var unit_detail: UnitDetail:
	set(value):
		unit_detail = value
		# スプライト情報があればAnimatedSprite2Dに反映
		if value && value.unit_sprite && $AnimatedSprite2D:
			$AnimatedSprite2D.frames = value.unit_sprite
		# nullの場合はスプライトをクリア
		if value == null:
			$AnimatedSprite2D.frames = null
		notify_property_list_changed()
                
@export var move_range = 3      # 移動可能範囲
@export var move_speed = 0.2    # 移動速度
@export var tile_size = Vector2i(16, 16) # タイルサイズ

@onready var animation: AnimatedSprite2D = $AnimatedSprite2D

var tween: Tween
var is_selected = false         # 選択状態
var is_action_done = false      # 行動済みフラグ
var previous_position: Vector2  # 直前の位置

func _ready():
	# Area2Dのinput_eventシグナルに接続
	$Area2D.input_event.connect(_on_input_event)
	# エネミーユニットの場合はスプライトを左右反転
	if unit_detail && unit_detail.unit_type == UnitDetail.UnitType.ENEMY:
		animation.flip_h = true

# ユニット選択時の処理
func _on_input_event(viewport, event, shape_idx):
	# 行動済みまたはHP0の場合は何もしない
	if unit_detail.unit_health <= 0 or is_action_done:
		return
	# マウスボタン押下で選択状態を切り替え、シグナル発行
	if event is InputEventMouseButton and event.pressed:
		is_selected = !is_selected
		if is_selected:
			SignalBus.unit_selected.emit(self)

# 指定パスに沿ってユニットを移動
func move_path(path: Array[Vector2i]):
	previous_position = position
	# プレイヤーユニットの場合、移動開始シグナル発行
	if unit_detail.unit_type == UnitDetail.UnitType.PLAYER:
		SignalBus.unit_moved.emit(true)
	for i in path.size():
		# 既存のTweenが動作中なら停止
		if tween && tween.is_running():
			tween.kill()
		tween = get_tree().create_tween()
		var pos = path[i] * tile_size
		pos = pos + (tile_size / 2)
		pos = Vector2(pos.x, pos.y)
		tween.tween_property(self, "position", pos, move_speed)
		animation.play("move")
		await tween.finished
	animation.play("default")
	# プレイヤーユニットの場合、移動終了シグナル発行
	if unit_detail.unit_type == UnitDetail.UnitType.PLAYER:
		SignalBus.unit_moved.emit(false)


# 行動状態をリセット
func reset_action():
	is_action_done = false

# 行動済み状態にし、HPが残っていればスプライトを暗くする
func action_done():
	is_action_done = true
	if unit_detail.unit_health != 0:
		$AnimatedSprite2D.self_modulate = Color(0.7, 0.7, 0.7, 1)

# スプライトの色を元に戻す
func clear_action():
	$AnimatedSprite2D.self_modulate = Color(1, 1, 1, 1)



@export var unit_detail: UnitDetail:
	set(value):
		unit_detail = value
		if value && value.unit_sprite && $AnimatedSprite2D:
			$AnimatedSprite2D.frames = value.unit_sprite
		if value == null:
			$AnimatedSprite2D.frames = null
		notify_property_list_changed()

func _on_input_event(viewport, event, shape_idx):
	if unit_detail.unit_health <= 0 or is_action_done:
		return
	if event is InputEventMouseButton and event.pressed:
		is_selected = !is_selected
		if is_selected:
			SignalBus.unit_selected.emit(self)

func move_path(path: Array[Vector2i]):
	...
	for i in path.size():
		if tween && tween.is_running():
			tween.kill()
		tween = get_tree().create_tween()
		var pos = path[i] * tile_size + (tile_size / 2)
		tween.tween_property(self, "position", pos, move_speed)
		animation.play("move")
		await tween.finished
	animation.play("default")

func action_done():
	is_action_done = true
	if unit_detail.unit_health != 0:
		$AnimatedSprite2D.self_modulate = Color(0.7, 0.7, 0.7, 1)

func clear_action():
	$AnimatedSprite2D.self_modulate = Color(1, 1, 1, 1)